Control de almacén en Excel: inventario, kárdex e indicadores paso a paso
Desde la primera lista de productos hasta el tablero que le presentas a gerencia. Seis etapas en orden, cada una con su video, sus fórmulas y su plantilla gratis. Sin macros hasta la última.
Cómo se mueve un producto por tu almacén
Cada etapa de la ruta es un paso de ese recorrido. Puedes seguirlas en orden o saltar a la que necesitas hoy.
¿Por dónde empiezo?
Etapa 1 · unos 20 minutos
Arma tu catálogo de productos
Antes de registrar un solo movimiento necesitas una lista única de productos. Es la hoja de la que van a leer todas las demás, y la mayoría de los descuadres empiezan aquí: el mismo producto escrito de tres maneras distintas.
Las columnas mínimas
| Columna | Para qué sirve |
|---|---|
| Código | Identifica el producto sin ambigüedad. Es lo que vas a escribir (o escanear) en cada movimiento. |
| Descripción | El nombre que entiende cualquiera: «Tornillo autorroscante 1/2 pulgada». |
| Unidad | Unidad, caja de 12, kilo, metro. Se decide una vez y no se mezcla. |
| Ubicación | Pasillo, estante o zona. Ahorra tiempo en el despacho y en el conteo. |
| Stock mínimo | Por debajo de este número hay que reponer. Lo usarás en la etapa 4. |
| Costo de referencia | Último costo de compra. Te sirve para valorizar rápido mientras armas el kárdex. |
Tres reglas que evitan el descuadre
- Un código por producto, nunca repetido. Para comprobarlo, en una columna auxiliar:
=CONTAR.SI(A:A;A2)>1. Si devuelve VERDADERO, ese código está dos veces. - La unidad no se mezcla. Si compras por caja y vendes por unidad, el catálogo registra la unidad y la compra se convierte al registrarla.
- Convierte la lista en Tabla (selecciona y pulsa Ctrl+T). Así las listas desplegables y las fórmulas que leen el catálogo crecen solas cuando agregas productos.
Si quieres escanear en lugar de escribir
Con una fuente de código de barras, el mismo catálogo imprime etiquetas, y un lector de códigos funciona como un teclado: escribe el código en la celda activa sin instalar nada. Lo tienes explicado paso a paso en cómo hacer códigos de barras en Excel, con una fuente libre incluida.
Al terminar esta etapa tienes
- Una hoja «Productos» con un código único por fila
- Unidad y ubicación definidas para cada producto
- Un stock mínimo escrito por producto
Plantilla de esta etapa
Códigos de barra en Excel con la fuente Code 39 incluida, lista para imprimir etiquetas de tu catálogo.
Codigo de barras en Excel para inventario (plantilla gratis)
Etapa 2 · unos 30 minutos
Registra entradas y salidas: el control de stock
Este es el corazón del almacén: cada movimiento en una fila y el stock calculado por fórmula, nunca escrito a mano. Si el stock se escribe a mano, tarde o temprano deja de cuadrar y nadie sabe por qué.
La estructura que funciona
Tres bloques: Productos (el catálogo de la etapa 1), Entradas (fecha, código, cantidad, proveedor o documento) y Salidas (fecha, código, cantidad, destino o documento). Pueden ser tres hojas o tres bloques en la misma hoja; lo importante es que el código sea siempre el mismo.
La fórmula del stock
=C2+SUMAR.SI(Entradas!$B:$B;A2;Entradas!$C:$C)-SUMAR.SI(Salidas!$B:$B;A2;Salidas!$C:$C)
En la hoja Productos: A2 es el código y C2 el stock inicial. En Entradas y Salidas, la columna B es el código y la C la cantidad. Si tu Excel usa coma como separador, cambia cada ; por ,. En un Excel en inglés la función se llama SUMIF.
Lista desplegable de códigos
En las hojas de movimientos, selecciona la columna del código y ve a Datos → Validación de datos → Lista, con origen en la columna de códigos del catálogo. Es lo que impide que alguien escriba «TORN-01» donde el código era «TOR-01», que es la causa más común de un producto que «desaparece».
El control que caza los errores
=CONTAR.SI(D:D;"<0")
Cuenta los productos con stock negativo. Un negativo siempre es una salida mal registrada o una entrada olvidada: búscalo antes de seguir.
Nunca borres un movimiento para corregir. Registra un ajuste: una entrada o una salida con el motivo «Ajuste de inventario». Así el historial cuadra y sabes cuándo y por qué cambió el stock.
Al terminar esta etapa tienes
- Hojas de entradas y salidas con fecha, código, cantidad y documento
- Stock por producto calculado con fórmula
- Lista desplegable en el código y el control de negativos
Plantilla de esta etapa
Control de stock básico: catálogo, entradas, salidas y stock al día con fórmulas.
Control de Stock Básico en Excel
Etapa 3 · unos 40 minutos
Valoriza tu inventario: kárdex con promedio ponderado
El control de stock te dice cuántas unidades tienes; el kárdex te dice cuánto valen. Es lo que te pide contabilidad para calcular el costo de ventas y el valor del inventario al cierre del mes.
Las columnas del kárdex
Un kárdex por producto, con tres grupos: lo que entra, lo que sale y lo que queda. En este ejemplo el saldo inicial está en la fila 9 y los movimientos empiezan en la 10:
| Grupo | Columnas |
|---|---|
| Datos | A fecha · B detalle |
| Entradas | C cantidad · D costo unitario · E total |
| Salidas | F cantidad · G costo unitario · H total |
| Saldo | I cantidad · J costo promedio · K total |
Las fórmulas, una sola vez
E10 =C10*D10 G10 =J9 H10 =F10*G10 I10 =I9+C10-F10 K10 =K9+E10-H10 J10 =SI(I10=0;0;K10/I10)
Sirven igual para una compra que para una venta, así que se arrastran hacia abajo sin cambiarlas. La salida se valora siempre al costo promedio de la fila anterior (G10 =J9): esa es toda la idea del promedio ponderado.
Cómo comprobar que está bien
El último saldo de la columna K tiene que ser igual al inventario inicial, más todas las compras, menos todo el costo de ventas:
=K9+SUMA(E10:E500)-SUMA(H10:H500)
Si no da lo mismo que tu último saldo, hay una fila con la fórmula rota o un valor escrito encima de una fórmula.
¿Promedio ponderado o PEPS?
Los dos son aceptados por las NIIF; UEPS no. El promedio suaviza los cambios de precio; PEPS deja el inventario valorizado a los precios más recientes. Elige uno y no lo cambies a mitad de año sin hablarlo con tu contador. En Perú, además, los registros de inventario tienen formato propio de SUNAT (12.1 y 13.1): tu contador te dirá cuál te corresponde.
La guía completa del kárdex, con cuatro clases en video, devoluciones y el formato SUNAT, está en kárdex en Excel con promedio ponderado.
Al terminar esta etapa tienes
- Un kárdex por producto con entradas, salidas y saldo
- El costo promedio recalculándose solo en cada movimiento
- La comprobación del saldo final cuadrando
Plantilla de esta etapa
Kárdex con promedio ponderado: el ejercicio completo con compras, ventas y devoluciones.
Valuación de inventario: Promedio Ponderado.
Etapa 4 · unos 30 minutos
Reposición: qué pedir y cuándo
Un almacén falla de dos maneras: se queda sin el producto que se vende o se llena del que no sale. Las dos se previenen con dos números por producto: el stock de seguridad y el punto de reorden.
Las dos fórmulas
Stock de seguridad = (consumo máximo diario - consumo promedio diario) x días de entrega Punto de reorden = consumo promedio diario x días de entrega + stock de seguridad
Cuando el stock de un producto baja hasta el punto de reorden, se hace el pedido. El stock de seguridad es el colchón para los días en que se vende más de lo normal mientras llega la compra.
Pruébalo con tus números
El consumo diario sale de tus salidas
=SUMAR.SI(Salidas!$B:$B;A2;Salidas!$C:$C)/90
Salidas del producto en el periodo dividido entre los días del periodo. Usa un periodo reciente (por ejemplo, los últimos 90 días) y no el año entero si tu negocio tiene temporadas.
El semáforo en la hoja
=SI(D2<=H2;"Pedir ya";SI(D2<=2*H2;"Atento";"OK"))
D2 es el stock actual y H2 el punto de reorden. Después, Inicio → Formato condicional → Resaltar reglas de celdas → Texto que contiene: rojo para «Pedir ya», ámbar para «Atento» y verde para «OK».
Del semáforo a la orden de compra
Cuando un producto se pone en rojo, el siguiente documento es la orden de compra. Si tienes más de un proveedor, compara precios antes de emitirla: el cuadro comparativo de proveedores en Excel marca solo el más barato de cada línea, y el formato de orden de compra en Excel la deja lista para enviar.
Al terminar esta etapa tienes
- Stock de seguridad y punto de reorden por producto
- El semáforo marcando qué pedir
- La orden de compra lista para el producto en rojo
Plantilla de esta etapa
Formato de orden de compra con proveedores y lugar de entrega, listo para imprimir o mandar en PDF.
Formato de Orden de Compra en Excel
Etapa 5 · unos 40 minutos
Indicadores de almacén: los números que se revisan cada mes
Con las etapas anteriores ya tienes todos los datos. Ahora toca convertirlos en cinco o seis números que te dicen si el almacén va bien, y que puedes presentar en una reunión sin explicar fila por fila.
Los indicadores que importan
| Indicador | Cómo se calcula | Qué te dice |
|---|---|---|
| Rotación de inventario | Costo de ventas ÷ inventario promedio | Cuántas veces renuevas el inventario en el periodo. |
| Días de inventario | Días del periodo ÷ rotación | Cuántos días te dura el inventario al ritmo actual. |
| Cobertura por producto | Stock actual ÷ consumo promedio diario | Para cuántos días te alcanza cada producto. |
| Exactitud del inventario | Productos sin diferencia ÷ productos contados | Cuánto se parece tu Excel a lo que hay en el estante. |
| Quiebres de stock | Productos con stock 0 ÷ productos activos | Qué parte del catálogo no puedes vender hoy. |
| Pedidos completos | Pedidos despachados completos ÷ pedidos totales | Si cumples al cliente a la primera. |
| Inventario sin movimiento | Valor sin salidas en 90 días ÷ valor total | Cuánto dinero está parado en el estante. |
Calcula tu rotación
El costo de ventas y los inventarios salen del kárdex de la etapa 3, valorizados al costo, no al precio de venta. Mezclarlos es el error que más infla la rotación.
Clasificación ABC: no todos los productos merecen el mismo cuidado
Ordena los productos por valor de consumo (cantidad que sale × costo) de mayor a menor y calcula el porcentaje acumulado. Con el valor en la columna E y los datos desde la fila 2:
F2 =SUMA($E$2:E2)/SUMA($E$2:$E$500) G2 =SI(F2<=80%;"A";SI(F2<=95%;"B";"C"))
La convención más usada: A hasta el 80 % del valor, B hasta el 95 % y C el resto. Los productos A son pocos y concentran casi todo el dinero: son los que se cuentan más a menudo y los que nunca deben faltar.
La toma de inventario
Cuenta lo que hay en el estante, anótalo junto al stock del Excel y calcula la diferencia (conteo menos sistema). No hace falta contarlo todo de una vez: el conteo cíclico cuenta un grupo cada semana, con más frecuencia los productos A. Toda diferencia se corrige con un ajuste registrado, igual que en la etapa 2.
Un tablero vale lo que vale el registro. Si la exactitud del inventario sale baja, arregla la etapa 2 antes de dedicarle tiempo al tablero.
Para armar el tablero con ayuda de la IA, tienes el prompt completo en prompts de IA para Excel y siete formas paso a paso en dashboard con IA.
Al terminar esta etapa tienes
- Rotación, días de inventario y cobertura calculados
- Productos clasificados en A, B y C
- Un conteo con su exactitud y sus ajustes registrados
Plantilla de esta etapa
Base de inventario de 30 productos y un dashboard ya terminado para comparar con el tuyo.
Base de datos de inventario para dashboard con IA (plantilla gratis)
Videos de apoyo
Etapa 6 · cuando la hoja se queda corta
Automatiza cuando la hoja se quede corta
Todo lo anterior funciona con fórmulas, sin macros. Llega un momento en que el problema ya no es Excel sino el tiempo: escribir los movimientos, revisar el semáforo producto por producto, rehacer el reporte del mes.
Señales de que te toca automatizar
- Registras movimientos todos los días.
- Más de una persona toca el archivo.
- Armas el reporte del mes a mano.
- Necesitas alertas sin revisar fila por fila.
- Te piden el kárdex valorizado y lo rehaces cada cierre.
Las plantillas premium de esta ruta
Control de Stock Básico V1
Entradas, salidas, stock al día, alertas de stock mínimo y tablero, con macros que hacen el trabajo repetitivo. Pago único.
Ver la plantillaFunciona en Microsoft Excel para Windows.
Kárdex valorizado automático
El kárdex de cada producto armado solo a partir de tus movimientos, con promedio ponderado y el resumen listo para contabilidad.
Avísame cuando salgaTablero de indicadores de almacén
Rotación, cobertura, quiebres, clasificación ABC y exactitud del inventario en un tablero que se actualiza con tus datos.
Avísame cuando salga
Tu kit de almacén gratis
Las seis plantillas de la ruta. Cada una está en su artículo, con la explicación completa y el botón de descarga.
En menos de un minuto
Los videos cortos del canal sobre inventario y kárdex. Se reproducen aquí mismo.
Dudas frecuentes
¿Qué diferencia hay entre control de stock, inventario y kárdex?
El control de stock lleva cantidades: cuántas unidades entran, salen y quedan. El inventario es el conjunto de productos que tienes en un momento dado, y la toma de inventario es contarlos. El kárdex añade el valor: a qué costo entra y sale cada unidad y cuánto vale lo que queda.
¿Necesito macros para llevar el almacén en Excel?
No. Las cinco primeras etapas funcionan solo con fórmulas que existen desde Excel 2007. Las macros sirven para ahorrar tiempo cuando el volumen crece, y por eso solo aparecen en la etapa 6.
¿Funciona en Google Sheets?
Las fórmulas sí: SUMAR.SI, CONTAR.SI y SI existen en Sheets (en inglés, SUMIF, COUNTIF e IF). Lo que no funciona en Sheets son las macros de las plantillas premium.
¿Cuántos productos aguanta Excel?
Excel admite más de un millón de filas por hoja, así que el límite casi nunca es la cantidad. Lo que vuelve lento un archivo son miles de fórmulas que leen columnas enteras. Cuando eso pase, convierte los rangos en Tablas y limita las fórmulas a las filas que usas.
¿Uso promedio ponderado o PEPS?
Los dos son aceptados por las NIIF; UEPS no. El promedio ponderado es más fácil de llevar en Excel y suaviza los cambios de precio. Lo importante es elegir uno, mantenerlo y confirmarlo con tu contador.
¿Cada cuánto debo contar el inventario?
Depende del valor de cada producto. Una pauta común es contar los productos A cada mes, los B cada trimestre y los C una o dos veces al año, en lugar de cerrar el almacén para contarlo todo de una vez.
¿Puedo usar un lector de código de barras con Excel?
Sí. Un lector USB funciona como un teclado: escribe el código en la celda donde esté el cursor y pulsa Enter. No hace falta instalar nada en Excel.
¿Prefieres verlo todo en orden en el canal? Las listas de reproducción siguen la misma ruta.